(* dm at mayart.de, 2004

Adobe Illustrator CS
Erstellt Schnittmarken um ausgewähltes Objekt.

Das Skript muss im Apple Skripteditor als *.scpt gespeichert und kann
unter Programme > Adobe Illustrator CSx > Vorgaben > Skripte abgelegt werden. 
Nach Neustart von Illustrator findet man es im Menü Datei > Skripten. 

Es geht auch mit dem Skript Menü in OS X (installieren mit AppleScript Utility in Programme > Applescript)
oder besser mit FastScripts: <http://www.red-sweater.com/fastscripts/index.html>.
Hier liegen die Skripte in ~/Library/Scripts/...

*)

tell application "Adobe Illustrator"
	activate
	if (count of documents) > 0 then
		set MeinItem to selection of current document
		
		if MeinItem is not {} then
			set MeinItem to item 1 of selection of current document
			set {x, y, x2, y2} to geometric bounds of MeinItem
			set selection to {}
			set default filled of document 1 to false
			set default stroked of document 1 to true
			
			try
				set A1 to 2.5 * 2.83464
				
				set L1 to 7.5 * 2.83464
				
				set LinienSt to 0.2 --(text returned of (display dialog ¬
				
				set Registration to (get last spot of current document)
				
				my Formatecken(x, y, x2, y2, A1, L1, LinienSt, Registration)
				
			on error number -128 -- userCanceledErr				
			end try
		else
			activate
			display dialog "Bitte ein Rechteck auswählen!"
		end if
	end if
	
end tell

on Formatecken(x, y, x2, y2, A1, L1, LinienSt, Registration)
	tell application "Adobe Illustrator"
		try
			set L2 to (L1 + A1) as real
			set untersteEbene to make new layer ¬
				at end of current document with properties {name:"Formatecken"}
			
			set groupRef to make new group item at beginning of last layer of current document
			
			--Senkrechte Marke für Punkt oben links
			set p1 to (y + A1)
			set p2 to (y + L2)
			make new path item at end of groupRef ¬
				with properties {entire path:{{x, p1}, {x, p2}} ¬
				, filled:false, stroked:true, stroke color:{tint:100.0, spot:Registration} ¬
				, stroke width:LinienSt, stroke overprint:false, closed:false}
			
			--Senkrechte Marke für Punkt oben rechts	
			make new path item at end of groupRef ¬
				with properties {entire path:{{x2, p1}, {x2, p2}} ¬
				, filled:false, stroked:true, stroke color:{tint:100.0, spot:Registration} ¬
				, stroke width:LinienSt, stroke overprint:false, closed:false}
			
			--Passer Oben 
			set Px1 to x + ((x2 - x) / 2)
			make new path item at end of groupRef ¬
				with properties {entire path:{{Px1, (p1 + A1)}, {Px1, p2}} ¬
				, filled:false, stroked:true, stroke color:{tint:100.0, spot:Registration} ¬
				, stroke width:LinienSt, stroke overprint:false, closed:false}
			set Pyz1 to y + A1 + L1 / 2
			set Pxz1 to Px1 - L1
			set Pxz2 to Px1 + L1
			make new path item at end of groupRef ¬
				with properties {entire path:{{Pxz1, Pyz1}, {Pxz2, Pyz1}} ¬
				, filled:false, stroked:true, stroke color:{tint:100.0, spot:Registration} ¬
				, stroke width:LinienSt, stroke overprint:false, closed:false}
			
			--Senkrechte Marke für Punkt unten links
			set p1 to (y2 - A1)
			set p2 to (y2 - L2)
			make new path item at end of groupRef ¬
				with properties {entire path:{{x, p1}, {x, p2}} ¬
				, filled:false, stroked:true, stroke color:{tint:100.0, spot:Registration} ¬
				, stroke width:LinienSt, stroke overprint:false, closed:false}
			
			--Senkrechte Marke für Punkt unten rechts	
			make new path item at end of groupRef ¬
				with properties {entire path:{{x2, p1}, {x2, p2}} ¬
				, filled:false, stroked:true, stroke color:{tint:100.0, spot:Registration} ¬
				, stroke width:LinienSt, stroke overprint:false, closed:false}
			
			--Passer Unten 
			make new path item at end of groupRef ¬
				with properties {entire path:{{Px1, (p1 - A1)}, {Px1, p2}} ¬
				, filled:false, stroked:true, stroke color:{tint:100.0, spot:Registration} ¬
				, stroke width:LinienSt, stroke overprint:false, closed:false}
			set Py1 to y2 - A1 - L1 / 2
			make new path item at end of groupRef ¬
				with properties {entire path:{{Pxz1, Py1}, {Pxz2, Py1}} ¬
				, filled:false, stroked:true, stroke color:{tint:100.0, spot:Registration} ¬
				, stroke width:LinienSt, stroke overprint:false, closed:false}
			
			-- Waagrechte Marke für Punkt oben links	
			set p1 to (x - A1)
			set p2 to (x - L2)
			make new path item at end of groupRef ¬
				with properties {entire path:{{p1, y}, {p2, y}} ¬
				, filled:false, stroked:true, stroke color:{tint:100.0, spot:Registration} ¬
				, stroke width:LinienSt, stroke overprint:false, closed:false}
			
			-- Waagrechte Marke für Punkt unten links	
			make new path item at end of groupRef ¬
				with properties {entire path:{{p1, y2}, {p2, y2}} ¬
				, filled:false, stroked:true, stroke color:{tint:100.0, spot:Registration} ¬
				, stroke width:LinienSt, stroke overprint:false, closed:false}
			
			--Passer Links 
			set Py1 to y2 + ((y - y2) / 2) - L1
			set Py2 to Py1 + L1 * 2
			set Px1 to x - A1 - L1 / 2
			make new path item at end of groupRef ¬
				with properties {entire path:{{Px1, Py1}, {Px1, Py2}} ¬
				, filled:false, stroked:true, stroke color:{tint:100.0, spot:Registration} ¬
				, stroke width:LinienSt, stroke overprint:false, closed:false}
			set Pz1 to y2 + ((y - y2) / 2)
			make new path item at end of groupRef ¬
				with properties {entire path:{{(p1 - A1), Pz1}, {p2, Pz1}} ¬
				, filled:false, stroked:true, stroke color:{tint:100.0, spot:Registration} ¬
				, stroke width:LinienSt, stroke overprint:false, closed:false}
			
			--Waagrechte Marke für Punkt oben rechts	
			set p1 to (x2 + A1)
			set p2 to (x2 + L2)
			make new path item at end of groupRef ¬
				with properties {entire path:{{p1, y}, {p2, y}} ¬
				, filled:false, stroked:true, stroke color:{tint:100.0, spot:Registration} ¬
				, stroke width:LinienSt, stroke overprint:false, closed:false}
			
			--Waagrechte Marke für Punkt unten rechts	
			make new path item at end of groupRef ¬
				with properties {entire path:{{p1, y2}, {p2, y2}} ¬
				, filled:false, stroked:true, stroke color:{tint:100.0, spot:Registration} ¬
				, stroke width:LinienSt, stroke overprint:false, closed:false}
			
			--Passer Rechts 
			set Px1 to x2 + A1 + (L1 / 2)
			make new path item at end of groupRef ¬
				with properties {entire path:{{Px1, Py1}, {Px1, Py2}} ¬
				, filled:false, stroked:true, stroke color:{tint:100.0, spot:Registration} ¬
				, stroke width:LinienSt, stroke overprint:false, closed:false}
			make new path item at end of groupRef ¬
				with properties {entire path:{{(p1 + A1), Pz1}, {p2, Pz1}} ¬
				, filled:false, stroked:true, stroke color:{tint:100.0, spot:Registration} ¬
				, stroke width:LinienSt, stroke overprint:false, closed:false}
			
		end try
	end tell
end Formatecken